package {
	import flash.display.*;
	import flash.events.*;
	import flash.geom.*;
	import flash.text.*;
	import flash.utils.*;
	[SWF(backgroundColor="0x000000",width="600",height="600",frameRate="50")]
	public class LangtonsAnt extends Sprite {
		private var antDirection:Number = 1;
		
		private var antX:Number;
		private var antY:Number;
		private var antZ:Number;
		
		private var nextX:Number;
		private var nextY:Number;
		private var nextZ:Number;
		
		private var cellsX:Number = 50;
		private var cellsY:Number = 50;
		private var cellsZ:Number = 50;
		
		private var cellWidth:Number = 5;
		private var cellHeight:Number = 5;
		
		private var layerBitmapDatas:Array;
		private var layerBitmaps:Array;
		
		private var loopTimer:Timer;
		private var maxDirections:Number = 8;
	
		private var offColor:Number = 0x00000000;
		private var onColor:Number = 0xffffffff;
		private var displayText:TextField;
		private var displayFormat:TextFormat;
		
		private var iteration:Number = 0;
		
		private var gradientShape:Shape;
		private var spectrumBitmapData:BitmapData;
		
		public function LangtonsAnt() {
			addEventListener(Event.ADDED_TO_STAGE,init);
		}
		
		private function init(e:Event):void {
			removeEventListener(Event.ADDED_TO_STAGE,init);
			displayText = new TextField();
			displayText.x = stage.stageWidth-65;
			displayText.y = 0;
			displayText.width = 65;
			displayText.height = 65;
			displayText.border = true;
			displayText.borderColor=0xcccccc;
			displayText.background = true;
			displayText.backgroundColor=0xffffff;
			addChild(displayText);
			
			antX = Math.floor(cellsX/2);
			antY = Math.floor(cellsY/2);
			antZ = Math.floor(cellsZ/2);
			
			layerBitmapDatas = [];
			layerBitmaps = [];
			for(var i:Number = 0;i<cellsZ;i++) {
				var bd:BitmapData = new BitmapData(cellsX*cellWidth,cellsY*cellHeight,true,offColor);
				layerBitmapDatas.push(bd);
				var b:Bitmap= new Bitmap(bd);
				b.x = i*cellWidth + cellWidth
				b.y = i*cellHeight + cellHeight;
				//b.x = 100;
				//b.y = 100;
				b.alpha = .05;
				addChild(b);
				layerBitmaps.push(b);
			}
			
			gradientShape = new Shape();
			var m:Matrix = new Matrix();
			m.createGradientBox(cellsZ,1,0,0,0);
			gradientShape.graphics.beginGradientFill(
				GradientType.LINEAR,
				[0xff0000ff,0xff00ff00,0xffff0000],
				[1,1,1],
				[0,128,255],
				m
			);
			gradientShape.graphics.drawRect(0,0,cellsZ,1);
			gradientShape.graphics.endFill();
			gradientShape.y = 0;
			//addChild(gradientShape);
			spectrumBitmapData = new BitmapData(cellsZ,1);
			spectrumBitmapData.draw(gradientShape);
			
			
			
			
			loopTimer = new Timer(10);
			loopTimer.addEventListener(TimerEvent.TIMER,mainLoop);
			loopTimer.start();
		}
		
		private function mainLoop(e:TimerEvent):void {
			setLayerAlphas();	
			if(layerBitmapDatas[antZ].getPixel32(antX*cellWidth,antY*cellHeight)==offColor) {
				antDirection++;
				if(antDirection == maxDirections) antDirection = 0;
				layerBitmapDatas[antZ].fillRect(new Rectangle(antX*cellWidth,antY*cellHeight,cellWidth-1,cellHeight-1),spectrumBitmapData.getPixel32(antZ,0));
			} else {
				layerBitmapDatas[antZ].fillRect(new Rectangle(antX*cellWidth,antY*cellHeight,cellWidth-1,cellHeight-1),offColor);
				antDirection--;
				if(antDirection == -1) antDirection = maxDirections-1;
			}
			switch(antDirection) {
				case 0:
					antZ--;
					break;
				case 1:
					antX++;
					break;
				case 2:
					antY++;
					break;
				
				case 3:
					antX--;
					break;
				case 4:
					antZ++;
					break;
				case 5:
					antX++;
					break;
				
				case 6:
					antY--;
					break;
				case 7:
					antX--;
					break;

				
				default:
					break;
			}
			if(antY < 0) antY += cellsY;
			if(antY >= cellsY) antY -= cellsY;
			if(antX < 0) antX += cellsX;
			if(antX >= cellsX) antX -= cellsX;
			if(antZ < 0) antZ += cellsZ;
			if(antZ >= cellsZ) antZ -= cellsZ;
			displayText.text = "x: " + antX + "\ny: " + antY + "\nz: " + antZ + "\ni: " + iteration;
			iteration++;
			e.updateAfterEvent();
		}
		private function setLayerAlphas():void {
			layerBitmaps[antZ].alpha = 1;
			if(layerBitmaps[antZ-1])layerBitmaps[antZ-1].alpha = .5;
			if(layerBitmaps[antZ+1])layerBitmaps[antZ+1].alpha = .5;
			if(layerBitmaps[antZ-2])layerBitmaps[antZ-2].alpha = .1;
			if(layerBitmaps[antZ+2])layerBitmaps[antZ+2].alpha = .1;
/*				if(layerBitmaps[antZ-3])layerBitmaps[antZ-3].alpha = .05;
			if(layerBitmaps[antZ+3])layerBitmaps[antZ+3].alpha = .05;
		if(layerBitmaps[antZ-4])layerBitmaps[antZ-4].alpha = .4;
			if(layerBitmaps[antZ+4])layerBitmaps[antZ+4].alpha = .4;
			if(layerBitmaps[antZ-5])layerBitmaps[antZ-5].alpha = .3;
			if(layerBitmaps[antZ+5])layerBitmaps[antZ+5].alpha = .3;
			if(layerBitmaps[antZ-6])layerBitmaps[antZ-6].alpha = .2;
			if(layerBitmaps[antZ+6])layerBitmaps[antZ+6].alpha = .2;
			if(layerBitmaps[antZ-7])layerBitmaps[antZ-7].alpha = .1;
			if(layerBitmaps[antZ+7])layerBitmaps[antZ+7].alpha = .1;*/
		}
		
	}
}